{
  description = "a collection of personal nix configurations";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default-linux";

    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    hardware.url = "github:nixos/nixos-hardware";
    nix-colors.url = "github:misterio77/nix-colors";

    nix-index-database.url = "github:nix-community/nix-index-database";
    nix-index-database.inputs.nixpkgs.follows = "nixpkgs";

    niri.url = "github:sodiboo/niri-flake";

    hyprlock.url = "github:hyprwm/hyprlock";
    hyprlock.inputs.nixpkgs.follows = "nixpkgs";
    hypridle.url = "github:hyprwm/hypridle";

    catppuccin.url = "github:catppuccin/nix";

    waybar-catppuccin.url = "github:catppuccin/waybar";
    waybar-catppuccin.flake = false;
    fuzzel-catppuccin.url = "github:catppuccin/fuzzel";
    fuzzel-catppuccin.flake = false;
    rofi-catppuccin.url = "github:catppuccin/rofi";
    rofi-catppuccin.flake = false;
  };

  outputs = inputs @ { self, nixpkgs, systems, ... }:
    let
      inherit (lib.my) mapModules mapModulesRec mapHosts;
      eachSystem = nixpkgs.lib.genAttrs (import systems);

      lib = nixpkgs.lib.extend (final: prev: {
        my = import ./lib {
          inherit inputs;
          lib = final;
          pkgs = null;
        };
      });

      mkPkgs = system: pkgs: extraOverlays:
        import pkgs {
          inherit system;
          config.allowUnfree = true;
          config.allowAliases = true;
          overlays = extraOverlays ++ (lib.attrValues self.overlays);
        };

      pkgsFor = eachSystem (system:
        mkPkgs system nixpkgs [
          self.overlays.default
          inputs.niri.overlays.niri
        ]
      );
    in {
      lib = lib.my;

      overlays = (mapModules ./overlays import) // {
        default = final: prev: {
          my = self.packages.${final.stdenv.hostPlatform.system};
        };
      };

      packages = eachSystem (system: let
        pkgs = pkgsFor.${system};
      in
        mapModules ./packages (p: pkgs.callPackage p {})
      );

      nixosModules = mapModulesRec ./modules import;

      nixosConfigurations = mapHosts ./hosts { inherit pkgsFor; };
    };
}