{
  description = "a collection of personal nix configurations";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default-linux";

    home-manager.url = "github:nix-community/home-manager";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    hardware.url = "github:nixos/nixos-hardware";

    base16.url = "github:senchopens/base16.nix";

    nix-index-database.url = "github:nix-community/nix-index-database";
    nix-index-database.inputs.nixpkgs.follows = "nixpkgs";

    nixos-apple-silicon.url = "github:nix-community/nixos-apple-silicon";

    cachyos-kernel.url = "github:xddxdd/nix-cachyos-kernel/release";

    niri.url = "github:sodiboo/niri-flake/pull/1731/head";

    vicinae.url = "github:vicinaehq/vicinae";
    vicinae-extensions.url = "github:vicinaehq/extensions";
    vicinae-extensions.inputs.nixpkgs.follows = "nixpkgs";

    hyprlock.url = "github:hyprwm/hyprlock";
    hyprlock.inputs.nixpkgs.follows = "nixpkgs";

    nix-vscode-extensions.url = "github:nix-community/nix-vscode-extensions";

    catppuccin.url = "github:catppuccin/nix";

    tt-schemes.url = "github:tinted-theming/schemes";
    tt-schemes.flake = false;
  };

  outputs = inputs @ { self, nixpkgs, systems, ... }:
    let
      inherit (lib.my) mapModules mapModulesRec mapHosts;
      eachSystem = nixpkgs.lib.genAttrs (import systems);

      lib = nixpkgs.lib.extend (final: prev: {
        my = import ./lib {
          inherit inputs;
          lib = final;
          pkgs = null;
        };
      });

      commonNixpkgsConfig = {
        config.allowUnfree = true;
        config.allowAliases = true;
        overlays = [
          self.overlays.default
          inputs.cachyos-kernel.overlays.pinned
          inputs.niri.overlays.niri
          inputs.nix-vscode-extensions.overlays.default
        ] ++ (lib.attrValues self.overlays);
      };

      pkgsFor = eachSystem (system: import nixpkgs ({ inherit system; } // commonNixpkgsConfig));
    in {
      lib = lib.my;

      overlays = (mapModules ./overlays import) // {
        default = final: prev: {
          my = self.packages.${final.stdenv.hostPlatform.system};
        };
      };

      packages = eachSystem (system: let
        pkgs = pkgsFor.${system};
      in
        mapModules ./packages (p: pkgs.callPackage p {})
      );

      nixosModules = mapModulesRec ./modules import;

      nixosConfigurations = mapHosts ./hosts { inherit commonNixpkgsConfig; };
    };
}