59 lines
2.1 KiB
Nix
59 lines
2.1 KiB
Nix
{ lib, config, pkgs, system, inputs , ... }:
|
|
|
|
with lib;
|
|
let
|
|
cfg = config.modules.desktop.hypridle;
|
|
in {
|
|
options.modules.desktop.hypridle = {
|
|
enable = mkEnableOption "Enable hypridle, hyprland's idle daemon";
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = inputs.hypridle.packages.${system}.hypridle;
|
|
example = "pkgs.hypridle";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
hm.home.packages = [ cfg.package ];
|
|
hm.services.hypridle = {
|
|
enable = true;
|
|
package = cfg.package;
|
|
|
|
settings = {
|
|
general = {
|
|
lock_cmd = "${pkgs.procps}/bin/pidof hyprlock || ${lib.getExe config.modules.desktop.hyprlock.package}";
|
|
unlock_cmd = "${pkgs.procps}/bin/pkill -USR1 hyprlock";
|
|
|
|
before_sleep_cmd = "${pkgs.systemd}/bin/loginctl lock-session"; # lock the screen before sleeping
|
|
};
|
|
|
|
listener = [
|
|
{
|
|
timeout = 60;
|
|
on-timeout = "${lib.getExe pkgs.brightnessctl} -c backlight -s set 20"; # dim screen, save brightness state
|
|
on-resume = "${lib.getExe pkgs.brightnessctl} -c backlight -r"; # restore previous screen brightness state
|
|
}
|
|
{
|
|
timeout = 60;
|
|
on-timeout = "${lib.getExe pkgs.brightnessctl} -d '*:kbd_backlight' -s set 0"; # turn off keyboard backlight, save state
|
|
on-resume = "${lib.getExe pkgs.brightnessctl} -d '*:kbd_backlight' -r"; # restore previous keyboard backlight state
|
|
}
|
|
{
|
|
timeout = 60 * 2; # 2 min
|
|
on-timeout = "${pkgs.systemd}/bin/loginctl lock-session"; # lock computer
|
|
}
|
|
{
|
|
timeout = 60 * 15; # 15 min
|
|
on-timeout = "${pkgs.systemd}/bin/systemctl suspend"; # sleep/suspend
|
|
}
|
|
] ++ optional config.modules.desktop.hyprland.enable (let
|
|
hyprctl = "${config.modules.desktop.hyprland.package}/bin/hyprctl";
|
|
in {
|
|
timeout = 90; # 1.5 min
|
|
on-timeout = "${hyprctl} dispatch dpms off"; # turn off screen
|
|
on-resume = "${hyprctl} dispatch dpms on"; # turn it back on
|
|
});
|
|
};
|
|
};
|
|
};
|
|
}
|