rework lib and some general changes

lib/attrs.nix

@@ -0,0 +1,25 @@
+{lib, ...}: let
+  inherit (lib.lists) any count;
+  inherit (lib.attrsets) filterAttrs listToAttrs mapAttrs' mapAttrsToList;
+in rec {
+  # attrsToList
+  attrsToList = attrs:
+    mapAttrsToList (name: value: {inherit name value;}) attrs;
+
+  # mapFilterAttrs ::
+  #   (name -> value -> bool)
+  #   (name -> value -> { name = any; value = any; })
+  #   attrs
+  mapFilterAttrs = pred: f: attrs: filterAttrs pred (mapAttrs' f attrs);
+
+  # Generate an attribute set by mapping a function over a list of values.
+  genAttrs' = values: f: listToAttrs (map f values);
+
+  # anyAttrs :: (name -> value -> bool) attrs
+  anyAttrs = pred: attrs:
+    any (attr: pred attr.name attr.value) (attrsToList attrs);
+
+  # countAttrs :: (name -> value -> bool) attrs
+  countAttrs = pred: attrs:
+    count (attr: pred attr.name attr.value) (attrsToList attrs);
+}

lib/default.nix

@@ -1,17 +1,20 @@
 { inputs, lib, pkgs, ... }:
 
-lib.extend (self: super:
   let
-    inherit (lib) attrValues foldr;
+    inherit (lib.attrsets) attrValues;
+    inherit (lib.fixedPoints) makeExtensible;
+    inherit (lib.lists) foldr;
     inherit (modules) mapModules;
-    inherit (helpers) getSSH;
 
-    modules = import ./modules.nix { inherit lib; };
-    helpers = import ./helpers.nix { inherit lib; };
-  in {
-    _ = foldr (a: b: a // b) {} (attrValues (mapModules ./. (file: import file {
-      inherit pkgs inputs;
-      lib = self;
-    })));
-  }
-)
+    modules = import ./modules.nix {
+      inherit lib;
+      self.attrs = import ./attrs.nix {
+      	inherit lib;
+      	self = {};
+      };
+    };
+    mylib =
+      makeExtensible (self:
+        mapModules ./. (file: import file {inherit self lib pkgs inputs;}));
+  in 
+    mylib.extend (self: super: foldr (a: b: a // b) {} (attrValues super))

lib/helpers.nix

@@ -1,18 +0,0 @@
-{ lib, ... }:
-
-with lib;
-rec {
-  indexFrom = origin: name: item: list: foldr
-  (h: t:
-    if h.${origin} == name && hasAttr item h
-    then h.${item}
-    else t)
-  (error ''
-    No item at the origin point ${origin} with element ${name} found.
-    Please make sure that the item with that origin exists, and,
-    failing that, that it also has the requested item defined.
-  '')
-  list;
-
-  getSSH = name: keys: indexFrom "hostname" name "ssh" keys;
-}

lib/modules.nix

@@ -1,27 +1,43 @@
-{ lib, ... }:
-
-let
-  inherit (builtins) attrValues readDir pathExists;
-  inherit (lib) id filterAttrs hasPrefix hasSuffix nameValuePair removeSuffix mapAttrs' trace fix fold isAttrs;
+{
+  lib,
+  self,
+  ...
+}: let
+  inherit (builtins) attrValues readDir pathExists concatLists;
+  inherit (lib.attrsets) mapAttrsToList filterAttrs nameValuePair;
+  inherit (lib.strings) hasPrefix hasSuffix removeSuffix;
+  inherit (lib.trivial) id;
+  inherit (self.attrs) mapFilterAttrs;
 in rec {
-  mapModules' = dir: fn: dirfn:
-    filterAttrs
-      (name: type: type != null && !(hasPrefix "_" name))
-      (mapAttrs'
-        (name: type:
-          let path = "${toString dir}/${name}"; in
-          if type == "directory"
-          then nameValuePair name (dirfn path)
-          else if
-            type == "regular" &&
-            name != "default.nix" &&
-            hasSuffix ".nix" name
-          then nameValuePair (removeSuffix ".nix" name) (fn path)
-          else nameValuePair "" null
-        )
-        (readDir dir));
+  mapModules = dir: fn:
+    mapFilterAttrs (n: v: v != null && !(hasPrefix "_" n)) (n: v: let
+      path = "${toString dir}/${n}";
+    in
+      if v == "directory" && pathExists "${path}/default.nix"
+      then nameValuePair n (fn path)
+      else if v == "regular" && n != "default.nix" && hasSuffix ".nix" n
+      then nameValuePair (removeSuffix ".nix" n) (fn path)
+      else nameValuePair "" null) (readDir dir);
 
-  mapModules = dir: fn: mapModules' dir fn (path: if pathExists "${path}/default.nix" then fn path else null);
-  mapModulesRec = dir: fn: mapModules' dir fn (path: mapModulesRec path fn);
-  mapModulesRec' = dir: fn: fix (f: attrs: fold (x: xs: (if isAttrs x then f x else [x]) ++ xs) [] (attrValues attrs)) (mapModulesRec dir fn);
+  mapModules' = dir: fn: attrValues (mapModules dir fn);
+
+  mapModulesRec = dir: fn:
+    mapFilterAttrs (n: v: v != null && !(hasPrefix "_" n)) (n: v: let
+      path = "${toString dir}/${n}";
+    in
+      if v == "directory"
+      then nameValuePair n (mapModulesRec path fn)
+      else if v == "regular" && n != "default.nix" && hasSuffix ".nix" n
+      then nameValuePair (removeSuffix ".nix" n) (fn path)
+      else nameValuePair "" null) (readDir dir);
+
+  mapModulesRec' = dir: fn: let
+    dirs =
+      mapAttrsToList (k: _: "${dir}/${k}")
+      (filterAttrs (n: v: v == "directory" && !(hasPrefix "_" n))
+        (readDir dir));
+    files = attrValues (mapModules dir id);
+    paths = files ++ concatLists (map (d: mapModulesRec' d id) dirs);
+  in
+    map fn paths;
 }

lib/nixos.nix

@@ -1,21 +1,35 @@
-{ inputs, lib, pkgs, ... }:
-
-with lib;
 {
-  mkHost = path: attrs@{ system, ... }:
+  inputs,
+  lib,
+  pkgs,
+  self,
+  ...
+}: let
+  inherit (inputs.nixpkgs.lib) nixosSystem;
+  inherit (builtins) baseNameOf elem;
+  inherit (lib.attrsets) filterAttrs;
+  inherit (lib.modules) mkDefault;
+  inherit (lib.strings) removeSuffix;
+  inherit (self.modules) mapModules;
+in rec {
+  mkHost = path: attrs @ {system ? "aarch64-linux", ...}:
     nixosSystem {
       inherit system;
-      specialArgs = { inherit lib inputs system; };
+
+      specialArgs = {inherit lib inputs system;};
+
       modules = [
         {
           nixpkgs.pkgs = pkgs;
-          networking.hostName = mkDefault (removeSuffix ".nix" (baseNameOf path));
+          networking.hostName =
+            mkDefault (removeSuffix ".nix" (baseNameOf path));
         }
-        (filterAttrs (n: v: !elem n [ "system" ]) attrs)
-
-        ../.
-
+        (filterAttrs (n: v: !elem n ["system"]) attrs)
+        ../. # /default.nix
         (import path)
       ];
     };
+
+  mapHosts = dir: attrs @ {system ? system, ...}:
+    mapModules dir (hostPath: mkHost hostPath attrs);
 }